새길이 찾아가는 작은 세상

앞에서 만들었던 로켓과 대포알 날리기를 조합해서 로켓이 날아가는 모습으로 만들었습니다.

POV-Ray에서 한번 만든 개체(object)는 그 형태를 계속 유지하면서 회전(rotate), 이동(translate)시킬 수 있기 때문에 시간(clock)에 따라 위치와 로켓을 기울이면서 날아가게 만든 것입니다. 자세한 내용은 소스파일을 참조하시기 바랍니다.

이제 연기만 내 뿜으면서 날리면 제대로 된 로켓의 모습이 나올 것 같군요... 연기를 어떻게 만들어 낼지는 좀 더 연구해 보아야 겠습니다.

[새길]

--------------------------------------------------------------

// 파일이름 : Rocket2.pov

global_settings { assumed_gamma 1.7 }
global_settings { noise_generator 1 }
#include "colors.inc"
#include "textures.inc"

camera {
location <5, 3, -9>
right x*image_width/image_height
look_at <3, 3, 0>
}

light_source {<1500, 2500, -2500> color White}

plane{
<0, 1, 0>, 1
hollow
rotate <0.1, 0, 0>
texture {
pigment { Bright_Blue_Sky
translate <2, 0, 0>
}
finish { ambient 1 diffuse 0 }
}
scale 10000
}

plane{
<0, 1, 0>, 0
texture {
pigment { color rgb <0.90, 0.55, 0.35> }
normal { bumps 0.5 scale 0.025 }
finish { ambient 0.1 diffuse 0.9 }
}
}

fog {
fog_type 2
distance 100
color White
fog_offset 0.1
fog_alt 2.5
turbulence 1.8
}

#declare Engine = union {
cone {
<0, 0, 0>, 0.5, <0, 1.5, 0>, 0.25
scale <1, 1, 0.7>
translate <0, 0.5, 0>
texture { Chrome_Metal }
}

prism { -0.01, 0.01, 4,
<0.0, 0.0>, <0.8, 0.0>, <0.0, 1.5>, <0.0, 0.0>
rotate <-90, 0, 0> translate <0, 0.5, 0>
texture {
pigment { color White }
finish { ambient 0.1 diffuse 0.9 phong 1.0 }
}
}

difference {
cone { <0, 0.10, 0>, 0.28, <0, 0.50, 0>, 0.10 }
cone { <0, 0.09, 0>, 0.17, <0, 0.49, 0>, 0.09 }
translate <0.22, 0, 0>
texture { Chrome_Metal }
}
translate <0.25, 0, 0>
}

#declare Rocket = union {
object { Engine rotate <0, 0, 0> translate <0, 0, 0> }
object { Engine rotate <0, 90, 0> translate <0, 0, 0> }
object { Engine rotate <0, 180, 0> translate <0, 0, 0> }
object { Engine rotate <0, 270, 0> translate <0, 0, 0> }

cylinder {
<0, 0, 0>, <0, 5, 0>, 0.5
translate <0, 0.5, 0>
texture {
pigment { color White }
finish { ambient 0.2 diffuse 0.8 phong 1.0 }
}
}
cylinder { <0, 0, 0>, <0, 0.1, 0>,0.505 translate <0, 2.0, 0>
texture { Chrome_Metal }
}
cylinder { <0, 0, 0>, <0, 0.1, 0>,0.505 translate <0, 3.5, 0>
texture { Chrome_Metal }
}
cylinder { <0, 0, 0>, <0, 0.1, 0>,0.505 translate <0, 5.25, 0>
texture { Chrome_Metal }
}

cone {
<0, 0, 0>, 0.5 <0, 1.5, 0>, 0.25
translate <0, 5+0.5, 0>
texture { Chrome_Metal }
}

sphere {
<0, 0, 0>, 0.25 scale <1, 1.5, 1>
translate <0, 5.00+1.50+0.50, 0>
texture { Chrome_Metal }
}
}

#declare V0 = 10;
#declare G = 1;
#declare TH = 45;

#declare Vx = V0*cos(TH*pi/180);
#declare Vy = V0*sin(TH*pi/180)-G*clock;
#declare RotateAngle = 180/pi*atan2(Vy,Vx);

object { Rocket rotate <90-RotateAngle, 0, 0> translate <0, V0*sin(TH*pi/180)*clock - 0.5*G*clock*clock, V0*cos(TH*pi/180)*clock> }

--------------------------------------------------------------

;파일이름 : rocket2.ini

Antialias=Off

Antialias_Threshold=0.2
Antialias_Depth=3

Input_File_Name=rocket2.pov

Initial_Frame=1
Final_Frame=30
Initial_Clock=0
Final_Clock=13

Cyclic_Animation=on
Pause_when_Done=off

--------------------------------------------------------------

오늘은 대포알 날리기를 연습했습니다.

평평한 대지에 빨간 대포알이 날아가는 모습을 만들었습니다.

대포알은 포물선 운동을 하며 날아가게 만들었습니다....

공이 초기속력 로, 각도 로 날려 보낼 때 시간 t 가 지났을 때의 위치는

로 표현되고 이를 POV-Ray에서의 위의 그림과 같은 좌표계(왼손 좌표계)로 바꾸어 표현하면 Ball의 위치를 <0, y, x>값으로 표시하면 됩니다.

아래의 POV파일을 참고해 보시기 바랍니다.

내일은 진짜 대포도 만들고 부시란 놈을 표적으로만들어서 쏘려고 합니다. 내일을 기대해 주세요... 그다음에는 앞에서 만든 로켓도 쏠겁니다...

오늘도 좋은 하루 되십시오. [새길]

------------------------------------

//파일이름 : projectile2.pov

global_settings { assumed_gamma 1.7 }
global_settings { noise_generator 1 }
#include "colors.inc"
#include "textures.inc"

camera {
//location <9*sin(clock*pi/2), 3, -9*cos(clock*pi/2)>
location <5, 3, -9>
right x*image_width/image_height
look_at <3.0, 3.0, 0.0>
}

light_source {<1500, 2500, -2500> color White}

plane{
<0, 1, 0>, 1
hollow
rotate <0.1, 0, 0>
texture {
pigment { Bright_Blue_Sky
translate <2, 0, 0>
}
finish { ambient 1 diffuse 0 }
}
scale 10000
}

plane{
<0, 1, 0>, -0.5
texture {
pigment { color rgb <0.90, 0.55, 0.35> }
normal { bumps 0.5 scale 0.025 }
finish { ambient 0.1 diffuse 0.9 }
}
}

fog {
fog_type 2
distance 100
color White
fog_offset 0.1
fog_alt 2.5
turbulence 1.8
}

#declare Ball =
sphere {
<0, 0, 0>, 0.5
pigment { Red }
}

#declare TH = 45;
#declare V0 = 7;
#declare G = 1;
#declare Z = 0;
#declare T = 0;

object { Ball translate <0, V0*sin(TH*pi/180)*clock - 0.5*G*clock*clock, V0*cos(TH*pi/180)*clock> }

------------------------------------

;파일이름 : projectile2.ini

Antialias=Off

Antialias_Threshold=0.2
Antialias_Depth=3

Input_File_Name=projectile2.pov

Initial_Frame=1
Final_Frame=60
Initial_Clock=0
Final_Clock=11

Cyclic_Animation=on
Pause_when_Done=off

------------------------------------

POV-Ray로 로켓을 만들었습니다.

로켓 모양의 원본은 Fiedrich A. Lohmueller라는 분이 만든 로켓입니다. 그분은 인터넷에 POV-Ray튜토리얼 사이트를 운영하시는데 제가 자주 가서 공부하는 사이트입니다.

사이트 주소 : http://www.f-lohmueller.de/pov_tut/pov__eng.htm

로켓에는 각종 부품을 cone, cylinder, prism, sphere를 이용해서 만들고 이를 이어 붙여서 만들었습니다. 그냥 밋밋하게 그림 한장 나오는 것보다 움직이는 형태로 만들고 싶어서 camera의 위치를 오른쪽으로 올아가면서 촬영하는 형태로 변형해 보았습니다. 소스의 camera부분과 INI파일은 제가 만들고 나머지는 Lohmueller씨의 모양 그대로 입니다. 몸통의 cylinder의 색깔을 바꾸면 다양한 색의 로켓을 만들 수 있습니다...

오늘도 좋은 하루 되세요...[새길]

--------------------------------------------------

// 파일이름 : Rocker.pov

global_settings { assumed_gamma 1.7 }
global_settings { noise_generator 1 }
#include "colors.inc"
#include "textures.inc"

camera {
location <9*sin(clock*pi/2), 3, -9*cos(clock*pi/2)>
right x*image_width/image_height
look_at <0.0, 3.0, 0.0>
}

light_source {<1500, 2500, -2500> color White}

plane{
<0, 1, 0>, 1
hollow
rotate <0.1, 0, 0>
texture {
pigment { Bright_Blue_Sky
translate <2, 0, 0>
}
finish { ambient 1 diffuse 0 }
}
scale 10000
}

plane{
<0, 1, 0>, 0
texture {
pigment { color rgb <0.90, 0.55, 0.35> }
normal { bumps 0.5 scale 0.025 }
finish { ambient 0.1 diffuse 0.9 }
}
}

fog {
fog_type 2
distance 100
color White
fog_offset 0.1
fog_alt 2.5
turbulence 1.8
}

#declare Engine = union {
cone {
<0, 0, 0>, 0.5, <0, 1.5, 0>, 0.25
scale <1, 1, 0.7>
translate <0, 0.5, 0>
texture { Chrome_Metal }
}

prism { -0.01, 0.01, 4,
<0.0, 0.0>, <0.8, 0.0>, <0.0, 1.5>, <0.0, 0.0>
rotate <-90, 0, 0> translate <0, 0.5, 0>
texture {
pigment { color White }
finish { ambient 0.1 diffuse 0.9 phong 1.0 }
}
}

difference {
cone { <0, 0.10, 0>, 0.28, <0, 0.50, 0>, 0.10 }
cone { <0, 0.09, 0>, 0.17, <0, 0.49, 0>, 0.09 }
translate <0.22, 0, 0>
texture { Chrome_Metal }
}
translate <0.25, 0, 0>
}

#declare Rocket = union {
object { Engine rotate <0, 0, 0> translate <0, 0, 0> }
object { Engine rotate <0, 90, 0> translate <0, 0, 0> }
object { Engine rotate <0, 180, 0> translate <0, 0, 0> }
object { Engine rotate <0, 270, 0> translate <0, 0, 0> }

cylinder {
<0, 0, 0>, <0, 5, 0>, 0.5
translate <0, 0.5, 0>
texture {
pigment { color White }
finish { ambient 0.2 diffuse 0.8 phong 1.0 }
}
}
cylinder { <0, 0, 0>, <0, 0.1, 0>,0.505 translate <0, 2.0, 0>
texture { Chrome_Metal }
}
cylinder { <0, 0, 0>, <0, 0.1, 0>,0.505 translate <0, 3.5, 0>
texture { Chrome_Metal }
}
cylinder { <0, 0, 0>, <0, 0.1, 0>,0.505 translate <0, 5.25, 0>
texture { Chrome_Metal }
}

cone {
<0, 0, 0>, 0.5 <0, 1.5, 0>, 0.25
translate <0, 5+0.5, 0>
texture { Chrome_Metal }
}

sphere {
<0, 0, 0>, 0.25 scale <1, 1.5, 1>
translate <0, 5.00+1.50+0.50, 0>
texture { Chrome_Metal }
}
}

object { Rocket rotate <0, 0, 0> translate <0, 0, 0> }

--------------------------------------------------

;파일이름 : rocket.ini

Antialias=On

Antialias_Threshold=0.2
Antialias_Depth=3

Input_File_Name=rocket.pov

Initial_Frame=1
Final_Frame=30
Initial_Clock=0
Final_Clock=1

Cyclic_Animation=on
Pause_when_Done=off

--------------------------------------------------

김선일씨의 명복을 빕니다...

연 삼일째 아무것도 하지 못했습니다. 이놈의 나라가 어떻게 돌아가려고 하는 것인지...

망할놈의 나라... 사람 하나도 살려내지 못하는 나라... 파병을 안한다고만 하면 한 사람의 목숨을 건질 수 있는 간단한 일을 가지고 미국놈들의 눈치를 봐야 하는 나라... 언제까지 미국놈들, 아니 부시의 똥이나 닦아주어야 하는지...

아무것도 안하고 있으면 미칠것 같아서 다시 POV-Ray연습을 시작했습니다.

앞에서 만든 while루프를 이용해서 그리는데 clock함수를 이용해서 다음 그림처럼 구부러지게 만들어 보았습니다.

앞의 소스에서 바뀐것이라고는 y축 값에 clock*이라는 것을 붙여준 것 뿐입니다. clock은 정해진 구간, 예를 들어 60장을 그릴 때는 60까지의 구간을 0에서 1까지 변화시켜주는 함수입니다. 60장을 그리고자 한다면 ini파일을 만들어 주어야 하는데 다음과 같이 만들어 주면 됩니다.

---------------------------------------------------

; 파일이름 : loopdemo006.ini

Antialias=Off

Antialias_Threshold=0.2
Antialias_Depth=3

Input_File_Name=loopdemo006.pov

Initial_Frame=1
Final_Frame=60
Initial_Clock=0
Final_Clock=1

Cyclic_Animation=on
Pause_when_Done=off

---------------------------------------------------

위의 ini파일을 만들고 나서 INI파일을 위의 파일로 지정하고 아래의 POV파일을 랜더링 하면 모두 60장의 bmp파일을 만들어 냅니다. 그리고 그 파일들을 애니메이션 제작 프로그램(저는 Animation Shop Pro를 사용했습니다)으로 gif나 avi로 만들어 주시면 됩니다.

---------------------------------------------------

/* 파일이름 : loodemo006.pov */

#include "colors.inc"

camera {
location <5.0, 10.0, -10.0>
look_at <0.0, -2.0, 0.0>
right x*image_width/image_height
}

background { White }

light_source {
<100, 100, -100>, White
}

#declare Ball =
sphere {
<0, 0, 0>, 0.25
texture {
pigment { color rgb<1, 0.7, 0> }
finish {
ambient 0.1
diffuse 0.9
phong 1
}
}
}

#declare Step = 0.5;

#declare Z = -5;
#declare EndZ = 5;

#while (Z < (EndZ + Step))
#declare X = -5;
#declare EndX = 5;

#while (X < (EndX + Step))
object { Ball translate <X, clock*sin(X)*sin(Z), Z> }
#declare X = X + Step;
#end

#declare Z = Z + Step;
#end
---------------------------------------------------

오늘은 여기까지... 다시한번 김선일씨의 명복을 빕니다. 부디 하늘나라에서 편히눈을 감으시기 바랍니다... [새길]

비가 많이 내렸습니다. 태풍의 직접적인 영향이 아니었는데도 비가 많이 내렸습니다. 이곳 고한에도 비가 너무 많이 내려 내심 걱정을 많이 했는데, 큰 피해는 없이 지나간 듯 합니다.

어제는 나팔을 만들어 보았는데 오늘은 while루프를 이용해서 반복해서 개체를 그리는 연습을 했습니다.

가운데에 노란색 공을 하나 그려 개체로 만든 후 while 루프 안에 넣어서 x축 방향으로 -5에서 5까지 0.5간격으로 배열한 것입니다.

#include "colors.inc"

camera {
location <5.0, 10.0, -10.0>
look_at <0.0, -2.0, 0.0>
right x*image_width/image_height
}

background { White }

light_source {
<100, 100, -100>, White
}

#declare Ball =
sphere {
<0, 0, 0>, 0.25
texture {
pigment { color rgb<1, 0.7, 0> }
finish {
ambient 0.1
diffuse 0.9
phong 1
}
}
}

#declare Step = 0.5;

#declare X = -5;
#declare EndX = 5;
#while (X <(EndX + Step))
object { Ball translate <X, 0, 0> }
#declare X = X + Step;
#end

<<x축 방향으로 나열한 공의 모습>>

다시 z축으로 while루프를 만들어 x축으로 줄긋는 나열하는 것을 반복해서 사각형 형태로 배열해 보았습니다. 아래의 소스는 위의 소스의 #declare X = -5; 로 시작되는 부분(파란색으로 표시된 부분)이하를 바꿔주면 됩니다.

#declare Z = -5;
#declare EndZ = 5;

#while (Z < (EndZ + Step))
#declare X = -5;
#declare EndX = 5;

#while (X < (EndX + Step))
object { Ball translate <X, 0, Z> }
#declare X = X + Step;
#end

#declare Z = Z + Step;
#end

<<X-Z축으로 공을 배열한 모습>>

평평한 배열이 보기 그래서 약간의 굴곡을 주기 위해 소스의 while 루프 속의 object { Ball transdlate <X, 0, Z> }의 y축값을 바꾸어 보았습니다.

<< object { Ball translate <X, sin(X), Z> } 인 경우 >>

<< object { Ball translate <X, sin(Z), Z> } 인 경우 >>

<< object { Ball translate <X, sin(X)*sin(Z), Z> } 인 경우

오늘은 여기까지입니다... 오늘도 행복한 하루 되세요...

몇 일 전부터 POV-Ray라는 프로그램을 연습하고 있습니다. 3D렌더링 프로그램이지요.

지금까지 연습한 것을 기초로 하늘이의 나팔을 보면서 나팔을 랜더링 해보았습니다.

아직은 POV-Ray의 모든 기능을 익힌 것이 아니어서 좀 어색하지만 그런데로 모양이 나온 듯 합니다.

랜더링 된 모습과 실제 나팔의 모양 비교

랜더링 된 나팔

3D-Max와 같은 전문적인 렌더링 프로그램이 아니고 직접 프로그램을 짜듯이 코딩을 해야 하는 프로그램이서 하나 하나를 만들 때 시간은 좀 걸리지만 부속품들을 하나 하나 디자인하면서 이어나가는 재미가 있습니다. 무엇보다도 마음에 드는 것은 프리웨어라 공짜로 사용할 수 있다는 것이죠. 또한 윈도건 리눅스건 관계 없이 사용할 수 도 있고요. 원래 리눅스프로그램을 윈도로 옮겨온 것입니다.

좀 더 많은 기능을 익히면서 만든 작품(?)을 올려 놓도록 하겠습니다... [새길]